/*************************************************************************
       CLOCK MODIFIER PREVIEW FILE FOR PERSISTENCE OF VISION 3.x
**************************************************************************

Created by Chris Colefax, 24 June 1997
Updated 7 August 1998: updated for POV-Ray 3.1

NOTE: This file requires that ClockMod.inc be installed
See "ClockMod.htm" for more information.

*************************************************************************/

// CHECK PREVIEW PARAMETERS
// ************************
   #declare _CM_tempver2 = version; #version 3.0;
   #declare clock_preview = true;
   #ifndef (graph_continuous) #declare graph_continuous = false; #end
   #ifndef (graph_thickness)  #declare graph_thickness  = .02;   #end
   #ifndef (graph_only)       #declare graph_only       = false; #end
   #ifdef  (graph_smoothness) #declare _CM_clockint = 1 / graph_smoothness; #else #declare _CM_clockint = 1 / 100; #end

// ADD CAMERA AND LIGHT
// ********************
   #if (graph_only = false)
      camera {location <.5, .5, -2> look_at <.5, .5, 0> angle 45}
      light_source {<5, 5, -20> rgb <1, 1, 1>}
   #end

// CREATE GRAPH OBJECT
// *******************
   union {
      box {<0, 0, 0>, <1, 1, .01> pigment {checker rgb .4, rgb .7 scale .1}}
      #declare mclock = 0; #include "ClockMod.inc"
      sphere {<0, mclock, 0>, graph_thickness}
      #declare _CP_cpoint = <0, mclock, 0>;
      #declare _CM_x = _CM_clockint; #while (_CM_x < 1 + _CM_clockint)
         #declare mclock = _CM_x; #include "ClockMod.inc"
         #if (graph_continuous = false)
            sphere {<_CM_x, mclock, 0>, graph_thickness}
         #else
            #declare _CP_ppoint = _CP_cpoint;
            #declare _CP_cpoint = <_CM_x, mclock, 0>;
            cylinder {_CP_ppoint, _CP_cpoint, graph_thickness}
            sphere {_CP_cpoint, graph_thickness}
         #end
      #declare _CM_x = _CM_x + _CM_clockint; #end
      pigment {rgb <1, 0, 0>} finish {phong .3}}

   #declare clock_preview = false;
   #version _CM_tempver2;